DM42 Progs - Make It Tea

Try to learn something about everything, and everything about somethingThomas Huxley “Darwin's bulldog” (1824-1895)
Trace: • DM15L Info • HP-11C Info • Hints & Tips • HP-35s Info • Programs • DM41L Info • DM41X Info • Diaries • Blog • DM41X Ladybug Module
You are here: Home » Public Area » Calculators » Programs » DM42 Progs
This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
<-[[.:start]]


====== DM42 Progs ======

Using the Swiss Micros online encode/decode tool   

https://technical.swissmicros.com/decoders/dm42/index.php

to convert a "RAW" file into readable text:

<code>
00 { 110-Byte Prgm }
01▸LBL "SWR"
02 INPUT "Fwd"
03 INPUT "Ref"
04 RCL "Ref"
05 RCL÷ "Fwd"
06 SQRT
07 STO "RHO"
08 1
09 RCL+ "RHO"
10 1
11 RCL- "RHO"
12 ÷
13 STO "SWR"
14 RCL "RHO"
15 LOG
16 20
17 ×
18 +/-
19 STO "RL"
20 VIEW "Ref"
21 PSE
22 VIEW "Fwd"
23 PSE
24 VIEW "RL"
25 PSE
26 VIEW "SWR"
27 PSE
28 RCL "Ref"
29 RCL "Fwd"
30 RCL "RL"
31 RCL "SWR"
32 END
</code>
<code>
00 { 41-Byte Prgm }
01▸LBL ".flc"
02 MVAR "freq"
03 MVAR "C"
04 MVAR "L"
05 RCL "L"
06 RCL "C"
07 ×
08 SQRT
09 PI
10 ×
11 2
12 ×
13 1/X
14 RCL "freq"
15 -
16 END
</code>
<code>
00 { 280-Byte Prgm }
01▸LBL "LCC"
02 INPUT "Vcc"
03 INPUT "PWR"
04 INPUT "freq"
05 RCL "Vcc"
06 X^2
07 RCL "PWR"
08 2
09 ×
10 ÷
11 STO "RL"
12 RCL "RL"
13 50
14 X≤Y?
15 XEQ "LCC"
16 RCL÷ "RL"
17 1
18 -
19 SQRT
20 STO "Qmin"
21 VIEW "Qmin"
22 PSE
23▸LBL 01
24 INPUT "Q"
25 RCL "Qmin"
26 X≥Y?
27 GTO 01
28 RCL "freq"
29 2
30 ×
31 PI
32 ×
33 STO "w"
34 RCL "Q"
35 X^2
36 1
37 +
38 RCL× "RL"
39 STO "B"
40 50
41 ÷
42 1
43 -
44 SQRT
45 STO "A"
46 RCL "Q"
47 RCL× "RL"
48 STO "XL"
49 RCL "B"
50 RCL "Q"
51 RCL- "A"
52 ÷
53 STO "XC1"
54 RCL "A"
55 50
56 ×
57 STO "XC2"
58 RCL "XL"
59 RCL÷ "w"
60 STO "L"
61 RCL "w"
62 RCL× "XC1"
63 1/X
64 STO "C1"
65 RCL "w"
66 RCL× "XC2"
67 1/X
68 STO "C2"
69 "Load"
70 AVIEW
71 PSE
72 VIEW "RL"
73 PSE
74 "Inductor"
75 AVIEW
76 PSE
77 VIEW "L"
78 PSE
79 "Shunt Cap"
80 AVIEW
81 PSE
82 VIEW "C2"
83 PSE
84 "Series Cap"
85 AVIEW
86 PSE
87 VIEW "C1"
88 PSE
89 RCL "RL"
90 RCL "L"
91 RCL "C2"
92 RCL "C1"
93 END
</code>
<code>
00 { 290-Byte Prgm }
01▸LBL "LCL"
02 INPUT "Vcc"
03 INPUT "PWR"
04 INPUT "freq"
05 RCL "Vcc"
06 X^2
07 RCL "PWR"
08 2
09 ×
10 ÷
11 STO "RL"
12 RCL "RL"
13 50
14 X≤Y?
15 XEQ "LCL"
16 RCL÷ "RL"
17 1
18 -
19 SQRT
20 STO "Qmin"
21 VIEW "Qmin"
22 PSE
23▸LBL 01
24 INPUT "Q"
25 RCL "Qmin"
26 X≥Y?
27 GTO 01
28 RCL "freq"
29 2
30 ×
31 PI
32 ×
33 STO "w"
34 RCL "Q"
35 X^2
36 1
37 +
38 RCL× "RL"
39 STO "A"
40 50
41 ÷
42 1
43 -
44 SQRT
45 STO "B"
46 RCL "RL"
47 RCL× "Q"
48 STO "XL1"
49 RCL "B"
50 50
51 ×
52 STO "XL2"
53 RCL "A"
54 RCL "Q"
55 RCL+ "B"
56 ÷
57 STO "XC"
58 RCL "XL1"
59 RCL÷ "w"
60 STO "L1"
61 RCL "XL2"
62 RCL÷ "w"
63 STO "L2"
64 RCL "XC"
65 RCL× "w"
66 1/X
67 STO "C"
68 "Load"
69 AVIEW
70 PSE
71 VIEW "RL"
72 PSE
73 "Input Inductor"
74 AVIEW
75 PSE
76 VIEW "L1"
77 PSE
78 "Shunt Cap"
79 AVIEW
80 PSE
81 VIEW "C"
82 PSE
83 "Output Inductor"
84 AVIEW
85 PSE
86 VIEW "L2"
87 PSE
88 RCL "RL"
89 RCL "L1"
90 RCL "C"
91 RCL "L2"
92 END
</code>
<code>
00 { 260-Byte Prgm }
01▸LBL "DTC"
02 INPUT "Z"
03 INPUT "Fmin"
04 INPUT "Fmax"
05 INPUT "L"
06 INPUT "Qu"
07 RCL "Fmin"
08 RCL× "Fmax"
09 SQRT
10 2
11 ×
12 PI
13 ×
14 STO "w"
15 RCL "L"
16 RCL "w"
17 X^2
18 ×
19 1/X
20 STO "Co"
21 RCL "w"
22 RCL "Fmax"
23 RCL- "Fmin"
24 2
25 ×
26 PI
27 ×
28 ÷
29 STO "Ql"
30 RCL "Co"
31 RCL "Ql"
32 2
33 SQRT
34 ×
35 ÷
36 STO "C12"
37 RCL "Ql"
38 2
39 SQRT
40 ×
41 STO "Qj"
42 RCL "Qj"
43 1/X
44 RCL "Qu"
45 1/X
46 -
47 1/X
48 STO "Qej"
49 RCL× "w"
50 RCL× "L"
51 STO "Rej"
52 RCL "Rej"
53 RCL× "Z"
54 RCL "Z"
55 X^2
56 -
57 SQRT
58 RCL× "w"
59 1/X
60 STO "Cjl"
61 RCL "Co"
62 RCL- "Cjl"
63 RCL- "C12"
64 STO "Cj"
65 "Tank Cap"
66 AVIEW
67 PSE
68 VIEW "Cj"
69 PSE
70 "Coupling Cap"
71 AVIEW
72 PSE
73 VIEW "C12"
74 PSE
75 "End Cap"
76 AVIEW
77 PSE
78 VIEW "Cjl"
79 PSE
80 RCL "Fmin"
81 RCL "Cj"
82 RCL "C12"
83 RCL "Cjl"
84 END
</code>
<code>
00 { 49-Byte Prgm }
01▸LBL ".VppdBm"
02 MVAR "Vpp"
03 MVAR "dBm"
04 RCL "Vpp"
05 X^2
06 400
07 ÷
08 1ᴇ-3
09 ÷
10 LOG
11 10
12 ×
13 RCL "dBm"
14 -
15 END
</code>
<code>
00 { 40-Byte Prgm }
01▸LBL ".LXl"
02 MVAR "L"
03 MVAR "freq"
04 MVAR "XL"
05 RCL "freq"
06 RCL× "L"
07 2
08 ×
09 PI
10 ×
11 RCL "XL"
12 -
13 END
</code>
<code>
00 { 42-Byte Prgm }
01▸LBL ".CXc"
02 MVAR "XC"
03 MVAR "freq"
04 MVAR "C"
05 RCL "XC"
06 RCL× "freq"
07 RCL× "C"
08 2
09 ×
10 PI
11 ×
12 1
13 -
14 END
</code>
<code>
00 { 45-Byte Prgm }
01▸LBL ".S→RL"
02 MVAR "RL"
03 MVAR "SWR"
04 RCL "SWR"
05 1
06 -
07 RCL "SWR"
08 1
09 +
10 ÷
11 LOG
12 20
13 ×
14 +/-
15 RCL- "RL"
16 END
</code>
<code>
00 { 58-Byte Prgm }
01▸LBL ".S→RF"
02 MVAR "Ref"
03 MVAR "Fwd"
04 MVAR "SWR"
05 1
06 RCL "Ref"
07 RCL÷ "Fwd"
08 SQRT
09 +
10 1
11 RCL "Ref"
12 RCL÷ "Fwd"
13 SQRT
14 -
15 ÷
16 RCL- "SWR"
17 END
</code>
<code>
00 { 37-Byte Prgm }
01▸LBL ".VppW"
02 MVAR "Vpp"
03 MVAR "Watt"
04 RCL "Vpp"
05 X^2
06 400
07 ÷
08 RCL- "Watt"
09 END
</code>
<code>
00 { 160-Byte Prgm }
01▸LBL "OpBPF"
02 INPUT "freq"
03 INPUT "BW"
04 INPUT "Gain"
05 INPUT "C"
06 RCL "freq"
07 RCL÷ "BW"
08 STO "Q"
09 RCL "freq"
10 2
11 ×
12 PI
13 ×
14 STO "w"
15 RCL "Gain"
16 RCL "C"
17 RCL "Q"
18 2
19 ×
20 RCL "w"
21 RCL× "C"
22 ÷
23 STO "R3"
24 RCL "Q"
25 RCL "Gain"
26 RCL× "w"
27 RCL× "C"
28 ÷
29 STO "R1"
30 RCL "Q"
31 RCL "Q"
32 X^2
33 2
34 ×
35 RCL- "Gain"
36 RCL× "w"
37 RCL× "C"
38 ÷
39 STO "R2"
40 VIEW "R1"
41 PSE
42 VIEW "R2"
43 PSE
44 VIEW "R3"
45 RCL "freq"
46 RCL "R1"
47 RCL "R2"
48 RCL "R3"
49 END
</code>
<code>
00 { 51-Byte Prgm }
01▸LBL ".PD"
02 MVAR "R1"
03 MVAR "R2"
04 MVAR "Vin"
05 MVAR "Vout"
06 RCL "Vin"
07 RCL "R1"
08 RCL+ "R2"
09 ÷
10 RCL "Vout"
11 RCL÷ "R2"
12 -
13 END
</code>
<code>
00 { 178-Byte Prgm }
01 GTO ".S←→RL"
02▸LBL "Lmat"
03 INPUT "Rlo"
04 INPUT "Rhi"
05 RCL "Rhi"
06 RCL "Rlo"
07 X≥Y?
08 XEQ "Lmat"
09 RCL "Rhi"
10 RCL÷ "Rlo"
11 1
12 -
13 SQRT
14 STO "Q"
15 RCL× "Rlo"
16 STO "XL"
17 RCL "Rhi"
18 RCL÷ "Q"
19 STO "XC"
20 INPUT "freq"
21 RCL "freq"
22 2
23 ×
24 PI
25 ×
26 STO "w"
27 RCL "XL"
28 RCL÷ "w"
29 STO "L"
30 RCL "XC"
31 RCL× "w"
32 1/X
33 STO "C"
34 "Q"
35 AVIEW
36 PSE
37 VIEW "Q"
38 PSE
39 "Inductor"
40 AVIEW
41 PSE
42 VIEW "L"
43 PSE
44 "Capacitor"
45 AVIEW
46 PSE
47 VIEW "C"
48 PSE
49 RCL "Rlo"
50 RCL "Rhi"
51 RCL "L"
52 RCL "C"
53 END
</code>
<code>
00 { 251-Byte Prgm }
01▸LBL "Tmat"
02 INPUT "Rhi"
03 INPUT "Rlo"
04 INPUT "freq"
05 RCL "Rhi"
06 RCL "Rlo"
07 X>Y?
08 XEQ "Tmat"
09 RCL "Rhi"
10 RCL÷ "Rlo"
11 1
12 -
13 SQRT
14 STO "Qmin"
15 VIEW "Qmin"
16 PSE
17▸LBL 01
18 INPUT "Q"
19 RCL "Qmin"
20 X≥Y?
21 GTO 01
22 RCL "Q"
23 X^2
24 1
25 +
26 RCL× "Rlo"
27 STO "A"
28 RCL÷ "Rhi"
29 1
30 -
31 SQRT
32 STO "B"
33 RCL "Rlo"
34 RCL× "Q"
35 STO "XL1"
36 RCL "Rhi"
37 RCL× "B"
38 STO "XL2"
39 RCL "A"
40 RCL "Q"
41 RCL+ "B"
42 ÷
43 STO "XC"
44 RCL "freq"
45 2
46 ×
47 PI
48 ×
49 STO "w"
50 RCL "XL1"
51 RCL÷ "w"
52 STO "L1"
53 RCL "XL2"
54 RCL÷ "w"
55 STO "L2"
56 RCL "XC"
57 RCL× "w"
58 1/X
59 STO "C"
60 "L hi"
61 AVIEW
62 PSE
63 VIEW "L1"
64 PSE
65 "C shunt"
66 AVIEW
67 PSE
68 VIEW "C"
69 PSE
70 "L low"
71 AVIEW
72 PSE
73 VIEW "L2"
74 PSE
75 RCL "Q"
76 RCL "L1"
77 RCL "C"
78 RCL "L2"
79 END
</code>
<code>
00 { 135-Byte Prgm }
01▸LBL "Piatt"
02 INPUT "Att"
03 INPUT "Z"
04 RCL "Att"
05 20
06 +/-
07 ÷
08 10^X
09 STO "A"
10 1
11 RCL+ "A"
12 1
13 RCL- "A"
14 ÷
15 RCL× "Z"
16 STO "R1"
17 1
18 RCL "A"
19 X^2
20 -
21 2
22 RCL× "A"
23 ÷
24 RCL× "Z"
25 STO "R2"
26 "Shunt R1"
27 AVIEW
28 PSE
29 VIEW "R1"
30 PSE
31 "Series R2"
32 AVIEW
33 PSE
34 VIEW "R2"
35 PSE
36 "Shunt R3"
37 AVIEW
38 PSE
39 VIEW "R1"
40 PSE
41 RCL "Att"
42 RCL "R1"
43 RCL "R2"
44 RCL "R1"
45 END
</code>
<code>
00 { 144-Byte Prgm }
01▸LBL "MPad"
02 INPUT "Zh"
03 INPUT "Zl"
04 RCL "Zl"
05 RCL÷ "Zh"
06 STO "A"
07 1
08 RCL- "A"
09 SQRT
10 RCL× "Zh"
11 STO "R1"
12 RCL "Zl"
13 1
14 RCL- "A"
15 SQRT
16 ÷
17 STO "R2"
18 RCL "A"
19 1/X
20 1
21 -
22 SQRT
23 RCL "A"
24 1/X
25 SQRT
26 +
27 X^2
28 1/X
29 LOG
30 10
31 ×
32 +/-
33 STO "G"
34 "Loss"
35 AVIEW
36 PSE
37 VIEW "G"
38 PSE
39 "Series R(hiZ)"
40 AVIEW
41 PSE
42 VIEW "R1"
43 PSE
44 "Shunt R(loZ)"
45 AVIEW
46 PSE
47 VIEW "R2"
48 PSE
49 RCL "G"
50 RCL "R1"
51 RCL "R2"
52 END
</code>
<code>
00 { 141-Byte Prgm }
01▸LBL "Tatt"
02 INPUT "Att"
03 INPUT "Z"
04 RCL "Att"
05 20
06 ÷
07 10^X
08 STO "G"
09 RCL "G"
10 1
11 -
12 RCL "G"
13 1
14 +
15 ÷
16 RCL× "Z"
17 STO "R1"
18 STO "R2"
19 RCL "G"
20 RCL "G"
21 X^2
22 1
23 -
24 ÷
25 RCL× "Z"
26 2
27 ×
28 STO "R3"
29 "Series R1"
30 AVIEW
31 PSE
32 VIEW "R1"
33 PSE
34 "Shunt R3"
35 AVIEW
36 PSE
37 VIEW "R3"
38 PSE
39 "Series R2"
40 AVIEW
41 PSE
42 VIEW "R2"
43 PSE
44 RCL "Att"
45 RCL "R1"
46 RCL "R3"
47 RCL "R2"
48 END
</code>
<code>
00 { 151-Byte Prgm }
01▸LBL "Bias"
02 INPUT "Vcc"
03 INPUT "Hfe"
04 INPUT "Ie"
05 RCL "Vcc"
06 12
07 ÷
08 STO "Ve"
09 0.7
10 +
11 STO "Vb"
12 RCL "Ve"
13 RCL÷ "Ie"
14 STO "Re"
15 RCL "Ie"
16 RCL÷ "Hfe"
17 STO "Ib"
18 RCL "Vb"
19 10
20 RCL× "Ib"
21 ÷
22 STO "R2"
23 RCL "Vcc"
24 RCL- "Vb"
25 11
26 RCL× "Ib"
27 ÷
28 STO "R1"
29 RCL "Vcc"
30 2
31 ÷
32 STO "Vc"
33 RCL "Vcc"
34 RCL- "Vc"
35 RCL÷ "Ie"
36 STO "Rc"
37 RCL "R1"
38 RCL "R2"
39 RCL "Rc"
40 RCL "Re"
41 END
</code>
<code>
00 { 26-Byte Prgm }
01▸LBL "FIB"
02 STO "N"
03 1
04 ENTER
05 0
06▸LBL A
07 +
08 LASTX
09 X<>Y
10 DSE "N"
11 GTO A
12 END
</code>
<code>
00 { 10-Byte Prgm }
01▸LBL "Eng3"
02 ENG 03
03 END
</code>
<code>
00 { 10-Byte Prgm }
01▸LBL "Fix6"
02 FIX 06
03 END
</code>
<code>
00 { 19-Byte Prgm }
01▸LBL "SM"
02 STO 00
03 0
04 STO 01
05▸LBL 01
06 RCL 00
07 STO+ 01
08 DSE 00
09 GTO 01
10 RCL 01
11 END
</code>
<code>
00 { 49-Byte Prgm }
01▸LBL "BM"
02 0
03 STO 02
04 1.01234ᴇ6
05 STO 00
06 2.345
07 STO 01
08▸LBL 02
09 RCL 01
10 RCL 00
11 ×
12 RCL 01
13 -
14 RCL 00
15 ÷
16 RCL 01
17 ×
18 3.5
19 ÷
20 SQRT
21 1
22 STO+ 02
23 GTO 02
24 END
</code>
<code>
00 { 33-Byte Prgm }
01▸LBL "BMT"
02 56.26
03 STO 00
04 0
05 STO 02
06▸LBL 04
07 RCL 00
08 SIN
09 ASIN
10 COS
11 ACOS
12 TAN
13 ATAN
14 LN
15 E^X
16 1
17 STO+ 02
18 GTO 04
19 END
</code>
<code>
00 { 64-Byte Prgm }
01▸LBL "P→S"
02 RECT
03 INPUT "Rp"
04 INPUT "Xp"
05 RCL "Rp"
06 RCL÷ "Xp"
07 STO "Q"
08 X^2
09 1
10 +
11 RCL "Rp"
12 X<>Y
13 ÷
14 STO "Rs"
15 RCL "Q"
16 ×
17 STO "Xs"
18 RCL "Rs"
19 RCL "Xs"
20 COMPLEX
21 STO "Zs"
22 END
</code>
<code>
00 { 51-Byte Prgm }
01▸LBL "S→P"
02 RECT
03 INPUT "Rs"
04 INPUT "Xs"
05 RCL÷ "Rs"
06 STO "Q"
07 X^2
08 1
09 +
10 RCL× "Rs"
11 STO "Rp"
12 RCL÷ "Q"
13 STO "Xp"
14 RCL "Rp"
15 RCL "Xp"
16 END
</code>
<code>
00 { 97-Byte Prgm }
01▸LBL "Z→"
02 RECT
03 INPUT "Rs"
04 INPUT "Xs"
05 RCL "Rs"
06 RCL "Xs"
07 COMPLEX
08 STO "Zs"
09 50
10 -
11 RCL "Zs"
12 50
13 +
14 ÷
15 STO "Rho"
16 ABS
17 STO "P"
18 1
19 RCL+ "P"
20 1
21 RCL- "P"
22 ÷
23 STO "S"
24 RCL "P"
25 LOG
26 20
27 ×
28 STO "Rl"
29 RCL "Zs"
30 RCL "Rho"
31 RCL "S"
32 RCL "Rl"
33 POLAR
34 RTN
35 END
</code>
<code>
00 { 92-Byte Prgm }
01▸LBL "PIXCIR"
02 MVAR "R"
03 MVAR "X"
04 MVAR "Y"
05 VARMENU "PIXCIR"
06 STOP
07 EXITALL
08 2
09 STO "GrMod"
10 1
11 360
12 1ᴇ3
13 ÷
14 +
15 STO 01
16 CLLCD
17▸LBL 01
18 RCL "Y"
19 RCL "R"
20 RCL 01
21 IP
22 SIN
23 ×
24 -
25 RCL "X"
26 RCL "R"
27 RCL 01
28 IP
29 COS
30 ×
31 +
32 PIXEL
33 RCL 01
34 ISG 01
35 GTO 01
36 XEQ "PIXCIR"
37 END
</code>
<code>
00 { 204-Byte Prgm }
01▸LBL "BFil"
02 ENG 03
03 SF 00
04 INPUT "MHz"
05 1ᴇ6
06 ×
07 STO "F"
08 INPUT "N"
09 X<0?
10 CF 00
11 XEQ 06
12▸LBL 01
13 RCL "I"
14 IP
15 XEQ 00
16 FS? 00
17 1/X
18 STO IND "I"
19 ISG "I"
20 GTO 01
21 "Coefficients"
22 AVIEW
23 STOP
24 GTO 07
25▸LBL 08
26 RCL IND "I"
27 RCL "F"
28 2
29 ×
30 PI
31 ×
32 ÷
33 RTN
34▸LBL 07
35 XEQ 06
36▸LBL 03
37 RCL "I"
38 IP
39 2
40 ÷
41 FP
42 FS? 00
43 GTO 09
44 GTO 10
45▸LBL 09
46 "HPF"
47 AVIEW
48 X=0?
49 GTO 05
50 GTO 04
51 RTN
52▸LBL 10
53 "LPF"
54 AVIEW
55 X=0?
56 GTO 04
57 GTO 05
58 RTN
59▸LBL 04
60 XEQ 08
61 50
62 ×
63 STO IND "I"
64 ISG "I"
65 GTO 03
66 RTN
67▸LBL 05
68 XEQ 08
69 50
70 ÷
71 STO IND "I"
72 ISG "I"
73 GTO 03
74 RTN
75▸LBL 06
76 RCL "N"
77 ABS
78 1000
79 ÷
80 1
81 +
82 STO "I"
83 RTN
84▸LBL 00
85 2
86 ×
87 1
88 -
89 180
90 ×
91 RCL "N"
92 ABS
93 2
94 ×
95 ÷
96 SIN
97 2
98 ×
99 RTN
100 END


</code>


==== Page Info ====

Page created Thu May 26 17:32:54 2022 by John Pumford-Green

Page last updated: ~~LASTMOD~~





--- //John Pumford-Green 24/04/23 16:08//

**Back to [[|Top]] of page**

===== Further Information =====


{{tag>calculator dm42}}
Navigation

Search

Toolbox
